1 PRINT"[147][159]TO USE A JOYSTICK WITH THIS PROGRAM"
2 PRINT"YOU MUST FIRST LOAD THE MENU AND RUN"
3 PRINT"'POWER BASIC - KEYBOARD TO JOYSTICK'[159]."
4 PRINT"WHEN PROMPTED FOR THE KEY'S USED ENTER"
5 PRINT"I[159],M[159],J[159],K[159] FOR UP/DOWN/LEFT/RIGHT AND ANY"
6 PRINT"KEY FOR THE FIREBUTTON. THEN LOAD AND"
7 PRINT"RUN 'MN[159]' TO RELOAD THE MENU."
8 PRINT"  PRESS 'M'[159] TO RELOAD THE MENU"
9 PRINT"  PRESS ANY OTHER KEY TO RUN THE DEMO"
10 POKE198,0:WAIT198,1:GETMT$:IFMT$=""THEN10
11 IFMT$<>"M"THEN100
15 POKE53280,14:POKE53281,14:PRINT"[147][154]LOAD";CHR$(34);"NT";CHR$(34);",8"
16 A$=CHR$(13)+"RUN"+CHR$(13)
17 FORI=1TOLEN(A$):POKE630+I,ASC(MID$(A$,I)):NEXT:POKE198,I-1
18 NEW
99 STOP
100 POKE53281,6:PRINT"[147][159]"TAB(16)"*** KEY TO JOY DEMO ***":A=RND(0)
110 POKE53280,0:POKE53281,0:FORI=0TO19:POKE1083-I,160:POKE1084+I,160:NEXTI
120 FORI=0TO21:POKE1104+I*40,160:POKE1143+I*40,160:NEXTI
130 FORI=0TO19:POKE1984+I,160:POKE2023-I,160:NEXTI
140 DIMS(999):WH=292:WT=WH:D=1:POKEWH+1024,81:S(WH)=D:GOSUB320:GOSUB350
150 GETA$:D1=D
160 IFA$="J"THEND=-1
170 IFA$="K"THEND=1
180 IFA$="I"THEND=-40
190 IFA$="M"THEND=40
200 IFD=-D1THEND=D1
210 S(WH)=D:WH=WH+D
220 IFPEEK(WH+1024)=65THENSC=SC+10:GOSUB350:GOSUB320:GOSUB320:L=5:GOTO240
230 IFPEEK(WH+1024)<>32THEN270
240 POKEWH+1024,81:IFLTHENL=L-1:GOTO260
250 POKEWT+1024,32:WT=WT+S(WT)
260 FORT=1TO25:NEXTT:GOTO150
270 P=PEEK(WH+1024):POKEWH+1024,86:PRINT:PRINT:PRINTTAB(2)CHR$(18)"YOU RAN ";
280 IFP=81THENPRINT"OVER YOURSELF"
290 IFP=160THENPRINT"INTO A WALL"
300 PRINT:PRINTTAB(2)CHR$(18)"GAME OVER"
302 PRINTSPC(6)"PRESS ANY KEY TO PLAY AGAIN"
305 POKE198,0:WAIT198,1:GETMT$:IFMT$=""THEN305
306 RUN100
310 REM *** GROW MUSHROOMS ***
320 R=INT(RND(1)*960)+1064:IFPEEK(R)<>32THEN320
330 POKER,65:RETURN
340 REM *** PRINT SCORE ***
350 PRINTCHR$(19)"SCORE: "RIGHT$("0000"+MID$(STR$(SC),2),5):RETURN